# $Id: PKGBUILD 66590 2012-02-26 13:20:19Z lfleischer $
# Maintainer: Angel 'angvp' Velasquez <angvp[at]archlinux.com.ve>
# Contributor: Roman Kyrylych <Roman.Kyrylych@gmail.com>
# Contributor: William Rea <sillywilly@gmail.com>

pkgname=agave
pkgver=0.4.7
pkgrel=3
pkgdesc="An colorscheme designer for the Gnome desktop"
arch=('i686' 'x86_64')
url="http://home.gna.org/colorscheme"
license=('GPL')
depends=('gtkmm' 'libgnomeui' 'libglademm' 'gconfmm>=2.18.1' 'hicolor-icon-theme')
makedepends=('intltool' 'boost' 'gnome-doc-utils>=0.11.2')
install=agave.install
source=("http://download.gna.org/colorscheme/releases/$pkgname-$pkgver.tar.bz2"
        agave-0.4.7-mdv-fix-str-fmt.patch
        schemebox.patch)
md5sums=('93097881f28dcae1eca2800a763f77c3'
         'd96ddfe751d8fd4d13a443b94fafb0b6'
         'c41adfd52ecbf837f4338e67693640fc')

build() {
  cd "$srcdir/$pkgname-$pkgver"

  patch -Np1 -i "$srcdir/agave-0.4.7-mdv-fix-str-fmt.patch" # Fedora patch
  patch -Np1 -i "$srcdir/schemebox.patch" # gcs-schemebox patch

  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var --disable-scrollkeeper 
  make
}

package() {
  cd "$srcdir/$pkgname-$pkgver"

  make GCONF_DISABLE_MAKEFILE_SCHEMA_INSTALL=1 DESTDIR="$pkgdir" install

  mkdir -p "$pkgdir/usr/share/gconf/schemas"
  gconf-merge-schema "$pkgdir/usr/share/gconf/schemas/$pkgname.schemas" \
    "$pkgdir/etc/gconf/schemas"/*.schemas
  rm -rf "$pkgdir/usr/etc"

  sed -i "s/agave-icon.png/agave.png/" "$pkgdir/usr/share/applications/agave.desktop"
  rm -f "${pkgdir}/etc/gconf/schemas"/*.schemas
}