# $Id: PKGBUILD 78779 2012-10-24 13:52:59Z mtorromeo $
# Maintainer: Massimiliano Torromeo <massimiliano.torromeo@gmail.com>
# Contributor: Connor Behan <connor.behan@gmail.com>
# Contributor: henning mueller <henning@orgizm.net>

pkgname=audit
pkgver=2.2.1
pkgrel=3
pkgdesc='User space utilities for storing and searching the audit records generated by the audit subsystem in the Linux kernel.'
url=http://people.redhat.com/sgrubb/$pkgname
arch=(i686 x86_64)
depends=(krb5 libcap-ng)
makedepends=(libldap swig linux-headers python2)
license=(GPL)
options=(!libtool emptydirs)
backup=(
	etc/libaudit.conf
	etc/audit/audit.rules
	etc/audit/auditd.conf
	etc/audisp/audispd.conf
	etc/audisp/audisp-remote.conf
	etc/audisp/zos-remote.conf
	etc/audisp/plugins.d/af_unix.conf
	etc/audisp/plugins.d/audispd-zos-remote.conf
	etc/audisp/plugins.d/au-remote.conf
	etc/audisp/plugins.d/syslog.conf
)
source=(
	$url/$pkgname-$pkgver.tar.gz
	auditd.rc
	auditd.service
	python2.patch
)

build() {
	cd "$srcdir/$pkgname-$pkgver"
	patch -p0 -i "$srcdir/python2.patch"
	./configure \
		--prefix=/usr \
		--sysconfdir=/etc \
		--libexecdir=/usr/lib/audit \
		--with-python=yes \
		--enable-gssapi-krb5=yes \
		--with-libcap-ng=yes #--with-apparmor=yes
	make
}

package() {
	cd "$srcdir/$pkgname-$pkgver"
	make DESTDIR="$pkgdir" install

	install -Dm755 "$srcdir/auditd.service" "$pkgdir/usr/lib/systemd/system/auditd.service"

	cd "$pkgdir"
	install -m755 "$srcdir/auditd.rc" etc/rc.d/auditd
	install -d var/log/audit
	rm -rf etc/rc.d/init.d etc/sysconfig
}

sha256sums=('9865ca89f5b975ccf25441ddf45a874448f2bba944005aa8cd5e3c3148713a63'
            '42c0a4f6ebbd185f783320fd552541d15eb91029b83add21d1e0289ac2dda7ba'
            '3c7179f40216b594675f26bb73884406c8ac91577b609dd1ab9837f889954007'
            'e60c031c6354f41938447c439eadee77127307687a2c487a54fab884eeafd9c2')