# $Id: PKGBUILD 40729 2011-02-26 08:51:40Z ibiru $
# Maintainer : Ionut Biru <ibiru@archlinux.org
# Contributor: Abhishek Dasgupta <abhidg@gmail.com>

pkgname=blueman
pkgver=1.21
pkgrel=7
pkgdesc="GTK+ bluetooth manager"
arch=('i686' 'x86_64')
license=('GPL')
url="http://blueman-project.org"
depends=('python-notify' 'bluez' 'dbus-python' 'gtk2' 'pygobject' 'startup-notification' 'obex-data-server' 'polkit-gnome' 'xdg-utils' 'hicolor-icon-theme')
makedepends=('pyrex' 'intltool')
optdepends=('dnsmasq: For creating PAN network'
            'gconf: For gconf configuration support'
            'pulseaudio: To use the pulseaudio plugin'
            'notification-daemon: for desktop notifications'
            'libnotify: for desktop notifications'
            'modemmanager: for modem management service'
            'gnome-icon-theme:icon theme')
options=('!libtool')
install=$pkgname.install
source=(http://download.tuxfamily.org/blueman/${pkgname}-${pkgver}.tar.gz
        PulsePatch.patch)
md5sums=('26b70341b3d3da28da62c917c8b20377'
         'cdce55a57d7628ed8b6c7fcf4391f4f0')

build() {
    cd "${srcdir}/${pkgname}-${pkgver}"

    patch -Np1 -i "${srcdir}/PulsePatch.patch"

    # python2 fix
    for file in apps/blueman*; do
        sed -i 's_#!/usr/bin/python_#!/usr/bin/python2_' $file
    done

    ./configure --prefix=/usr \
        --sysconfdir=/etc \
        --libexecdir=/usr/lib/blueman \
        --with-no-runtime-deps-check
    make
    make DESTDIR="${pkgdir}" install
    echo "OnlyShowIn=GNOME;XFCE;" >> ${pkgdir}/etc/xdg/autostart/blueman.desktop
}