# Maintainer: jelle van der Waa <jelle@vdwaa.nl>
# Contributor: eric <eric@archlinux.org>
# Contributor: Tom Newsom <Jeepster@gmx.co.uk>

pkgname=bonnie++
pkgver=1.03e
pkgrel=7
pkgdesc="Based on the Bonnie hard drive benchmark by Tim Bray"
arch=('i686' 'x86_64' 'mips64el')
url="http://www.coker.com.au/bonnie++/"
license=('GPL')
depends=('perl')
source=(http://www.coker.com.au/bonnie++/$pkgname-$pkgver.tgz move_away_from_sbin.patch)
sha256sums=('cb3866116634bf65760b6806be4afa7e24a1cad6f145c876df8721f01ba2e2cb'
            'c100df652c26f38c950baaf3fe25a74d51ba830066f9d02d273cbb5fc5660814')

build() {
  cd $srcdir/${pkgname}-${pkgver}

  ./configure --prefix=/usr 
  sed -i "s:CFLAGS=-O2  -DNDEBUG \$(WFLAGS) \$(MORECFLAGS):CFLAGS=${CFLAGS}:" Makefile
  make
}

package() {
  cd $srcdir/${pkgname}-${pkgver}

  # https://www.archlinux.org/todo/move-files-to-usrbin-if-possible/
  patch -Np1 -i $srcdir/move_away_from_sbin.patch
  make prefix="${pkgdir}/usr" install

  install -d $pkgdir/usr/share/doc/bonnie++
  install -Dm644 $srcdir/$pkgname-$pkgver/readme.html $pkgdir/usr/share/doc/bonnie++/readme.html
}