# $Id: PKGBUILD 66594 2012-02-26 13:42:22Z lfleischer $
# Maintainer: Eric Belanger <eric@archlinux.org>
# Contributor: William Rea <sillywilly@gmail.com>

pkgname=buoh
pkgver=0.8.2
pkgrel=5
pkgdesc="A reader for online strips comics"
arch=('i686' 'x86_64')
url="http://buoh.steve-o.org/"
license=('GPL')
depends=('libgnomeui' 'libsoup>=2.4.0' 'gconf' 'hicolor-icon-theme')
makedepends=('gettext' 'intltool' 'pkgconfig')
install=buoh.install
source=("http://buoh.steve-o.org/downloads/${pkgname}-${pkgver}.tar.bz2"
        buoh-libsoup24.patch)
md5sums=('50474a8712ad20ab36d8f8058a4647fb'
         'c44f0e1828492a5d7d8efee764558fb4')
sha1sums=('29d702b485a901868f65116e753cb515b3e2a2c5'
          '012badf13e33818268b744e106bdcccfd8fc66ed')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  patch -p1 < ../buoh-libsoup24.patch
  autoconf

  ./configure --prefix=/usr --sysconfdir=/usr/share --disable-schemas-install
  make AM_CFLAGS=-lxml2
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="$pkgdir" install
}