# $Id: PKGBUILD 67882 2012-03-15 16:59:01Z lcarlier $
# Maintainer : Laurent Carlier <lordheavym@gmail.com>
# Contributor: dionydonny <dionydonny@gmail.com>
# Contributor: Ermanno <erm67@yahoo.it>

pkgname=chmsee
pkgver=1.99.08
pkgrel=3
arch=('i686' 'x86_64')
pkgdesc="A chm (MS HTML help file format) viewer based on xulrunner."
url="http://chmsee.googlecode.com/"
license=('GPL')
depends=('xulrunner>=11.0' 'chmlib' 'desktop-file-utils')
makedepends=('python2')
source=(chmsee-$pkgver.tar.gz::https://github.com/jungleji/chmsee/tarball/v$pkgver
        chmsee)
install=chmsee.install
md5sums=('9e54b72761f8e97e683c03e52ac1ac6c'
         'abc127caca8bccf9ac51cf937b75d0c2')

build() {
  cd ${srcdir}/jungleji-chmsee-*/src

  cp Makefile.arch Makefile
  #sed -i -e 's/python/python2/g' common.mk
  sed -i -e 's/10.*/11.*/g' ../application.ini

  make
}

package() {
  cd ${srcdir}/jungleji-chmsee-*

  install -d ${pkgdir}/usr/share/chmsee
  cp -a * ${pkgdir}/usr/share/chmsee 
  rm -r ${pkgdir}/usr/share/chmsee/src
  install -Dm644 data/chmsee.desktop.in \
    ${pkgdir}/usr/share/applications/chmsee.desktop
  # Fix FS#25152
  sed -i -e 's/_//g' ${pkgdir}/usr/share/applications/chmsee.desktop
  #
  install -d ${pkgdir}/usr/share/pixmaps
  install -Dm644 data/chmsee-icon.png ${pkgdir}/usr/share/pixmaps
  install -Dm755 ${srcdir}/chmsee ${pkgdir}/usr/bin/chmsee
#  install -d ${pkgdir}/usr/share/icons
#  cp -a data/icons/* ${pkgdir}/usr/share/icons/
}