# $Id: PKGBUILD 80665 2012-11-28 22:07:33Z plewis $
# Maintainer: Peter Richard Lewis <plewis@aur.archlinux.org>
# Contributor: Andrea Scarpino <andrea@archlinux.org>
# Contributor: Emanuele Rossi <newdna1510@yahoo.it>
# Contributor: Bram Schoenmakers <me@bramschoenmakers.nl>

pkgname=choqok
pkgver=1.3
pkgrel=4
pkgdesc="A Twitter/identi.ca/laconica client for KDE"
url='http://choqok.gnufolks.org/'
license=('GPL')
arch=('i686' 'x86_64' 'mips64el')
depends=('kdebase-runtime' 'qjson' 'qoauth' 'qca-ossl')
makedepends=('cmake' 'automoc4')
optdepends=('kdebase-konqueror: proxy support')
install="${pkgname}.install"
source=("http://downloads.sourceforge.net/${pkgname}/${pkgname}-${pkgver}.tar.bz2")
md5sums=('87eea4f2c23467fb021e3e6b794eb37d')

build() {
  cd "${srcdir}"
  mkdir build
  cd build
  cmake ../${pkgname}-${pkgver} \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr
  make
}

package() {
  cd "${srcdir}"/build
  make DESTDIR="${pkgdir}" install

  # This is already installed by kdepimlibs >= 4.9.80
  rm "${pkgdir}"/usr/share/apps/cmake/modules/FindQtOAuth.cmake
}