# $Id: PKGBUILD 96731 2013-09-03 16:12:39Z spupykin $
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: Sebastian Faltoni <sebastian.faltoni@gmail.com>

pkgname=dbmail
pkgver=3.1.4
pkgrel=2
pkgdesc="Fast and scalable sql based mail services"
arch=('i686' 'x86_64' 'mips64el')
depends=('gmime' 'libzdb' 'mhash' 'libevent')
makedepends=('asciidoc' 'xmlto' 'docbook-xsl' 'docbook-xml' 'postgresql-libs>=8.4.1'
	     'sqlite' 'libmysqlclient' 'libldap>=2.4.18' 'libsieve')
optdepends=('libldap: for LDAP authentication'
	    'libsieve: for dbmail-sieve'
	    'python2-mysql2pgsql: migrate from MySQL to PostreSQL')
url="http://www.dbmail.org"
license=('GPL')
options=('!libtool' 'zipman')
backup=(etc/xinetd.d/dbmail-imapd
	etc/xinetd.d/dbmail-pop3d
	etc/xinetd.d/dbmail-lmtpd
	etc/xinetd.d/dbmail-timsieved)
source=(http://www.dbmail.org/download/3.1/dbmail-${pkgver/_/-}.tar.gz
	dbmail.tmpfiles
	dbmail-imapd.service
	dbmail-lmtpd.service
	dbmail-pop3d.service
	dbmail-timsieved.service
	dbmail-imapd.xinetd
	dbmail-lmtpd.xinetd
	dbmail-pop3d.xinetd
	dbmail-timsieved.xinetd
	"boundary.patch::http://git.dbmail.eu/paul/dbmail/patch/?id=fd742e39b13ec45e4ecf2e175113a6a0120af27b"
	"crlf.patch::http://git.dbmail.eu/paul/dbmail/patch/?id=17a2e61917ae64b1f20039f49b70b9130b678c87")
md5sums=('0090bb7998469e963d2eb49b7d16ea3f'
         'c4b5793c5422b62a675d4c66ff7e9300'
         '5a6297cb03c8d0b424f978ea1d7402de'
         '070db88538af9833f003f4cb516d337b'
         '422f0399f97a780b7cab84443e8f429a'
         '15c7d367d4242aebac5f87649a2250aa'
         '890de13361afbdf4fed12d6d7eb53e66'
         '961593658cd596297d03d25eb9c9e98f'
         '4cb764894abd3914802e90602bf90a0c'
         'e78dc86355f9aaf24590bc7c6611162f'
         'e9f9c1140e77e3714fd2c3905b1760f1'
         'c86c4c2a4e9171ae8c0ad5692262b393')

prepare() {
  cd $srcdir/dbmail-${pkgver/_/-}/
  patch -p1 <$srcdir/boundary.patch
  patch -p1 <$srcdir/crlf.patch
}

build() {
  cd $srcdir/dbmail-${pkgver/_/-}/
  [ -f Makefile ] || ./configure \
    --prefix=/usr --sbindir=/usr/bin --sysconfdir=/etc \
    --with-ldap --with-sieve
  make
}

package() {
  cd $srcdir/dbmail-${pkgver/_/-}/
  make DESTDIR=$pkgdir install
  (cd man && make && make install DESTDIR=$pkgdir)

  mkdir $pkgdir/etc
  install -Dm644 dbmail.conf $pkgdir/etc/dbmail.conf.sample
  mkdir $pkgdir/usr/share/dbmail
  cp -r sql/* $pkgdir/usr/share/dbmail/
  cp -a contrib $pkgdir/usr/share/dbmail/
  cp dbmail.schema $pkgdir/usr/share/dbmail/

  for i in dbmail-imapd dbmail-lmtpd dbmail-pop3d dbmail-timsieved; do
    install -Dm0644 $srcdir/$i.service $pkgdir/usr/lib/systemd/system/$i.service
    install -Dm0644 $srcdir/$i.xinetd $pkgdir/etc/xinetd.d/$i
  done

  install -Dm0644 $srcdir/dbmail.tmpfiles $pkgdir/usr/lib/tmpfiles.d/dbmail.conf
}