# $Id: PKGBUILD 69507 2012-04-17 14:32:37Z bgyorgy $
# Maintainer: Balló György <ballogyor+arch at gmail dot com>

pkgname=deja-dup
pkgver=22.1
pkgrel=1
pkgdesc="Simple backup tool, that hides the complexity of backing up the Right Way and uses duplicity as the backend"
arch=('i686' 'x86_64' 'mips64el')
url="https://launchpad.net/deja-dup"
license=('GPL')
depends=('duplicity' 'gtk3' 'libgnome-keyring' 'libnotify' 'dconf' 'hicolor-icon-theme' 'xdg-utils')
makedepends=('vala' 'intltool' 'itstool' 'nautilus')
optdepends=('nautilus: backup extension')
options=('!libtool')
install=$pkgname.install
source=(http://launchpad.net/$pkgname/${pkgver%.*}/$pkgver/+download/$pkgname-$pkgver.tar.xz)
md5sums=('cbf7af6f0392ab9ef355a3aeb74c8a79')

build() {
  cd "$srcdir/$pkgname-$pkgver"
  sed -i 's/\"python\", \"-c\"/\"python2\", \"-c\"/' common/PythonChecker.vala

  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var --libexecdir=/usr/lib/$pkgname \
              --disable-static --disable-schemas-compile --without-unity
  make
}

package() {
  cd "$srcdir/$pkgname-$pkgver"

  make DESTDIR="$pkgdir/" install
}