# $Id: PKGBUILD 72942 2012-06-25 11:01:19Z spupykin $
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Maintainer: Judd Vinet <jvinet@zeroflux.org>
# Contributor: Giovanni Scafora <giovanni@archlinux.org>

pkgname=distcc
pkgver=3.1
pkgrel=7
pkgdesc="A distributed C, C++, Obj C compiler"
arch=('i686' 'x86_64' 'mips64el')
url="http://code.google.com/p/distcc/"
license=('GPL')
depends=('gcc' 'popt' 'avahi')
makedepends=('gtk2' 'pkgconfig' 'python2')
optdepends=('gtk2: for distccmon-gnome'
	    'python2')
backup=(etc/conf.d/distccd)
source=(http://distcc.googlecode.com/files/${pkgname}-${pkgver}.tar.bz2
        distccd
        distccd.conf.d)
md5sums=('a1a9d3853df7133669fffec2a9aab9f3'
         '1c918474372c09304772c20c4de484fa'
         '89aaf6e9072092e283465a14e83f0f94')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  [ -f Makefile ] || PYTHON=/usr/bin/python2 ./configure --prefix=/usr \
	--with-gtk \
	--sysconfdir=/etc \
	--mandir=/usr/share/man \
#	--without-avahi \

  make WERROR_CFLAGS= INCLUDESERVER_PYTHON=/usr/bin/python2
}

check() {
  cd "${srcdir}/${pkgname}-${pkgver}"
#  make TEST_PYTHON=/usr/bin/python2 check
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}/" INCLUDESERVER_PYTHON=/usr/bin/python2 install
  install -D -m644 ${srcdir}/distccd.conf.d ${pkgdir}/etc/conf.d/distccd
  install -D -m755 ${srcdir}/distccd ${pkgdir}/etc/rc.d/distccd

  install -d ${pkgdir}/usr/lib/${pkgname}/bin
  ln -sf /usr/bin/${pkgname} ${pkgdir}/usr/lib/${pkgname}/bin/cc
  ln -sf /usr/bin/${pkgname} ${pkgdir}/usr/lib/${pkgname}/bin/gcc
  ln -sf /usr/bin/${pkgname} ${pkgdir}/usr/lib/${pkgname}/bin/g++
  ln -sf /usr/bin/${pkgname} ${pkgdir}/usr/lib/${pkgname}/bin/c++
  ln -sf /usr/bin/${pkgname} ${pkgdir}/usr/lib/${pkgname}/bin/cpp
}