# $Id: PKGBUILD 63408 2012-02-02 10:00:55Z seblu $
# Maintainer: Sébastien Luttringer <seblu@aur.archlinux.org>

pkgname=drbd
pkgver=8.3.11
pkgrel=1
arch=('i686' 'x86_64')
pkgdesc='Userland tools for drbd block devices'
url='http://www.drbd.org'
license=('GPL2')
source=("http://oss.linbit.com/drbd/8.3/$pkgname-$pkgver.tar.gz"
        "$pkgname.rc"
        '01-remove-old-sanity-check.diff')
backup=('etc/drbd.conf' 'etc/drbd.d/global_common.conf')
md5sums=('e47a35a80143b72e9708844efbe2e608'
         '19236c6fe7a8c9191d67a4df15892b78'
         '24144d23b31f9ce66929fe989247c779')

build() {
  cd $pkgname-$pkgver
  # patch bad sanity check in makefile
  patch -p1 -i ../01-remove-old-sanity-check.diff
  ./configure \
    --prefix=/usr \
    --localstatedir=/var \
    --sysconfdir=/etc \
    --with-distro=generic \
    --with-utils \
    --with-bashcompletion \
    --with-udev \
    --without-km \
    --without-rgmanager \
    --without-pacemaker \
    --without-heartbeat \
    --without-xen \
    --with-initdir=/etc/rc.d
    #--with-legacy_utils \
  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install

  # move udev files to the right place
  install -d -m 755 "$pkgdir/lib"
  mv "$pkgdir/etc/udev" "$pkgdir/lib"

  # remove /var/lock
  rmdir "$pkgdir/var/lock"

  # replace 
  install -D -m 755 "$srcdir/$pkgname.rc" "$pkgdir/etc/rc.d/$pkgname"
}

# vim:set ts=2 sw=2 ft=sh et: