# $Id: PKGBUILD 101531 2013-11-27 02:32:12Z eric $
# Maintainer: Eric Bélanger <eric@archlinux.org>

pkgname=dvdisaster
pkgver=0.72.5
pkgrel=1
pkgdesc="Provides a margin of safety against data loss on CD and DVD media caused by aging or scratches"
arch=('i686' 'x86_64')
url="http://www.dvdisaster.com/"
license=('GPL')
depends=('gtk2')
options=('!makeflags')
install=dvdisaster.install
source=(http://dvdisaster.net/downloads/${pkgname}-${pkgver}.tar.bz2
        ${pkgname}-${pkgver}.tar.bz2.sig::http://dvdisaster.net/downloads/${pkgname}-${pkgver}.tar.bz2.gpg)
sha1sums=('cc89c7eaf838ba1a88be4ed1a567276a911f76b0'
          '7bffbbd282c009986938811ee6bd22d10b1a95f4')

prepare() {
  cd ${pkgname}-${pkgver}
  sed -i 's/dvdisaster48/dvdisaster/' contrib/dvdisaster.desktop
}

build() {
  cd ${pkgname}-${pkgver}
  ./configure --prefix=/usr \
    --mandir=/usr/share/man --docdir=/usr/share/doc \
    --localedir=/usr/share/locale \
    --with-nls=yes 
  make
}

package() {
  cd ${pkgname}-${pkgver}

  make BUILDROOT="${pkgdir}" install
  rm -f "${pkgdir}/usr/bin/dvdisaster-uninstall.sh"
  install -D -m 644 contrib/dvdisaster.desktop "${pkgdir}/usr/share/applications/dvdisaster.desktop"
  for i in 16 24 32 48 64 ; do
    install -D -m 644 contrib/dvdisaster${i}.png "${pkgdir}/usr/share/icons/hicolor/${i}x${i}/dvdisaster.png"
  done
}