# $Id: PKGBUILD 57590 2011-10-31 07:59:11Z spupykin $
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Maintainer: Mark Taylor <skymt0@gmail.com>

pkgname=dzen2
pkgver=0.8.5
pkgrel=7
arch=(i686 x86_64 'mips64el')
pkgdesc="X notification utility"
url="http://gotmor.googlepages.com/dzen"
license=("MIT")
depends=('libx11' 'libxpm' 'libxinerama' 'libxft')
makedepends=('gcc')
source=(http://gotmor.googlepages.com/$pkgname-$pkgver.tar.gz)
md5sums=('5978620c2124c8a8ad52d7f17ce94fd7')

build()
{
  cd $srcdir/dzen2-$pkgver

  CFLAGS=" ${CFLAGS} ${INCS} -DVERSION=\"${VERSION}\" -DDZEN_XINERAMA -DDZEN_XPM -DDZEN_XFT `pkg-config --cflags xft`"
  LIBS=" ${LDFLAGS} -L/usr/lib -lc -lX11 -lXinerama -lXpm `pkg-config --libs xft`"

  echo "CFLAGS=$CFLAGS" >>config.mk
  echo "LDFLAGS=$LIBS" >>config.mk

  make X11INC=/usr/include X11LIB=/usr/lib
  (cd $srcdir/dzen2-$pkgver/gadgets && make X11INC=/usr/include X11LIB=/usr/lib)
}

package() {
  cd $srcdir/dzen2-$pkgver
  make PREFIX=/usr MANPREFIX=/usr/man DESTDIR=$pkgdir install
  (cd $srcdir/dzen2-$pkgver/gadgets && make PREFIX=/usr MANPREFIX=/usr/man DESTDIR=$pkgdir install)
  install -m644 -D LICENSE $pkgdir/usr/share/licenses/dzen2/COPYING
}