# $Id: PKGBUILD 88204 2013-04-13 20:20:33Z alucryd $
# Maintainer: Maxime Gauduin <alucryd@gmail.com>

pkgname=ffmpegsource
pkgver=753
pkgrel=1
pkgdesc="A libav/ffmpeg based source library and Avisynth plugin for easy frame accurate access"
arch=('i686' 'x86_64' 'mips64el')
url="http://code.google.com/p/ffmpegsource/"
license=('MIT')
depends=('ffmpeg')
makedepends=('svn')
options=('!libtool')
source=("${pkgname}::svn+http://ffmpegsource.googlecode.com/svn/trunk/"
        'autoconf.patch')
sha256sums=('SKIP'
            'b09a7e9a08a16bdaf19d43c7ad8d3ec455f6fecec2f4f5ada417345343adda93')

pkgver() {
  cd "${SRCDEST}"/${pkgname}

  svnversion | tr -d [A-z]
}

prepare() {
  cd "${srcdir}"/${pkgname}

  patch -Np1 -i ../autoconf.patch
}

build() {
  cd "${srcdir}"/${pkgname}

  ./autogen.sh --prefix=/usr --enable-shared --disable-static
  make
}

package() {
  cd "${srcdir}"/${pkgname}

  make DESTDIR="${pkgdir}" install

  install -dm 755 "${pkgdir}"/usr/share/licenses/ffmpegsource
  install -m 644 COPYING "${pkgdir}"/usr/share/licenses/ffmpegsource/LICENSE
}

# vim: ts=2 sw=2 et: