# $Id: PKGBUILD 47655 2011-05-24 16:52:31Z schuay $
# Contributor: Jaroslaw Swierczynski <swiergot@aur.archlinux.org>
# Contributor: Roman Kyrylych <Roman.Kyrylych@gmail.com>

pkgname=glob2
pkgver=0.9.4.4
pkgrel=8
pkgdesc="RTS game which minimizes micro-management by automatically assigning tasks to units"
arch=('i686' 'x86_64')
url="http://www.globulation2.org/"
license=('GPL3')
depends=('boost-libs' 'sdl_net' 'sdl_image' 'sdl_ttf' 'libvorbis' 'speex' 'mesa' \
         'fribidi' 'desktop-file-utils')
makedepends=('scons' 'boost')
install=glob2.install
source=(http://dl.sv.nongnu.org/releases/${pkgname}/0.9.4/${pkgname}-${pkgver}.tar.gz \
	glob2-0.9.4.1-gcc44.patch)
md5sums=('94c527325f355a29a2807f8f18a6e6a8' 'b13cb1f73ece23bfc6413773678d583e')
sha1sums=('14aa8d840ef5f95a9af591789082fe2322fa8cad' '3e5ae81d85a727387a7049c3a0dfb3db930391b3')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  patch -Np0 -i "$srcdir/glob2-0.9.4.1-gcc44.patch"
  scons BINDIR="${pkgdir}/usr/bin" INSTALLDIR="${pkgdir}/usr/share"
}

package () {
  cd "${srcdir}/${pkgname}-${pkgver}"

  scons install
  find "${pkgdir}/usr/share" -type f -exec chmod 644 '{}' \;
  install -Dm644 data/icons/glob2-icon-48x48.png "${pkgdir}/usr/share/pixmaps/glob2-icon-48x48.png"
}