# $Id: PKGBUILD 69058 2012-04-08 21:20:04Z bgyorgy $
# Maintainer: Balló György <ballogyor+arch at gmail dot com>

pkgname=gnome-subtitles
pkgver=1.2
pkgrel=3
pkgdesc="Video subtitle editor for GNOME"
arch=('i686' 'x86_64')
url="http://gnomesubtitles.org/"
license=('GPL')
depends=('gstreamer0.10-base-plugins' 'gconf-sharp' 'gtkspell' 'desktop-file-utils')
makedepends=('intltool' 'gnome-doc-utils')
optdepends=('gstreamer0.10-good-plugins: Extra media codecs'
            'gstreamer0.10-bad-plugins: Extra media codecs'            
            'gstreamer0.10-ugly-plugins: Extra media codecs'
            'gstreamer0.10-ffmpeg: Extra media codecs')
options=('!libtool')
install=$pkgname.install
source=(http://downloads.sourceforge.net/$pkgname/$pkgname-$pkgver.tar.gz
        fix-help.patch)
md5sums=('b7f3175b7a189471821d809171121d62'
         '7645bc18812ea52137adddd6e87942d5')

build() {
  cd "$srcdir/$pkgname-$pkgver"
  patch -Np1 -i "$srcdir/fix-help.patch"

  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
              --disable-static --disable-schemas-install --disable-scrollkeeper \
              --with-gconf-schema-file-dir=/usr/share/gconf/schemas
  make
}

package() {
  cd "$srcdir/$pkgname-$pkgver"

  make DESTDIR="$pkgdir/" install
}