# $Id: PKGBUILD 71937 2012-06-03 21:24:21Z spupykin $
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: wahnby <wahnby@yahoo.fr>

pkgname=gnunet
pkgver=0.9.3
pkgrel=1
pkgdesc="A framework for secure peer-to-peer networking"
arch=('i686' 'x86_64' 'mips64el')
url="http://gnunet.org"
license=('GPL')
depends=('gmp' 'libgcrypt' 'libextractor' 'sqlite' 'curl'
	 'libmicrohttpd' 'libunistring')
makedepends=('gettext' 'pkgconfig')
backup=(etc/gnunetd.conf)
options=('!libtool' '!makeflags')
install=gnunet.install
source=(ftp://ftp.gnu.org/gnu/gnunet/gnunet-$pkgver.tar.gz{,.sig}
	gnunet.rc
	gnunet.conf.d
	defaults.conf)

build() {
  cd $srcdir/gnunet-$pkgver
  sed -i 's|contrib doc|doc|' Makefile.*
  [ -f Makefile ] || ./configure --prefix=/usr --without-mysql
  make
}

package() {
  cd $srcdir/gnunet-$pkgver
  make DESTDIR=$pkgdir install
  install -D -m0755 $srcdir/gnunet.rc $pkgdir/etc/rc.d/gnunetd
  install -D -m0644 $srcdir/gnunet.conf.d $pkgdir/etc/conf.d/gnunetd
  install -D -m0644 $srcdir/defaults.conf $pkgdir/etc/gnunetd.conf
  rm -rf $pkgdir/usr/include/libltdl $pkgdir/usr/lib/libltdl.* $pkgdir/usr/include/ltdl.h
}
md5sums=('4234ad22e3204941773632a1d0c2e0e8'
         '26135208534eb638f8585ccf19472c6f'
         '5baf691913b007fb33e365239e3f7217'
         'f161b46915736e4017e77ad735521453'
         '0fe23b2ca5b3fc47a0b5645e04406da0')