# $Id: PKGBUILD 79447 2012-11-05 19:27:31Z bgyorgy $
# Maintainer: Jaroslav Lichtblau <dragonlord@aur.archlinux.org>
# Contributor: Hugo Doria <hugo@archlinux.org>
# Contributor: Christer Solskogen (solskogen@carebears.mine.nu)

pkgname=gtranslator
pkgver=2.91.5
pkgrel=2
pkgdesc="An enhanced gettext po file editor for the GNOME"
arch=('i686' 'x86_64' 'mips64el')
url="http://projects.gnome.org/gtranslator/"
license=('GPL')
depends=('desktop-file-utils' 'gdl' 'gettext' 'gtksourceview3' 'gtkspell3' 'iso-codes' 'libgda' 'libpeas' 'gsettings-desktop-schemas' 'hicolor-icon-theme' 'dconf')
makedepends=('intltool' 'gnome-doc-utils' 'gucharmap' 'json-glib')
optdepends=('gucharmap: for charmap plugin'
            'json-glib: for open-tran plugin')
options=('!libtool')
install=$pkgname.install
changelog=$pkgname.changelog
source=(http://ftp.acc.umu.se/pub/GNOME/sources/$pkgname/2.91/$pkgname-$pkgver.tar.xz
        disable-dockbar.patch)
sha256sums=('7dcdabd5c2156bef98f35d2ec31798287d1721e400ea738fb3ccc2ff2ef186e6'
            '04647eb198291024e5a65564ad6be239b7af4472421a44c2d57ed5d6a8bb4384')

build() {
  cd ${srcdir}/${pkgname}-${pkgver}

  # Tempolary disable dockbar, because layout loading is completely broken with gdl 3.6
  patch -Np1 -i ${srcdir}/disable-dockbar.patch

  ./configure --prefix=/usr --sysconfdir=/etc --disable-schemas-compile
  make
}

package() {
  cd ${srcdir}/${pkgname}-${pkgver}

  make DESTDIR=${pkgdir} install
}