# $Id: PKGBUILD 72161 2012-06-09 09:50:29Z bgyorgy $
# Maintainer: Balló György <ballogyor+arch at gmail dot com>
# Contributor: Angel Velasquez <angvp@archlinux.org>
# Contributor: Wilson Pinto Júnior (N3RD3X) <n3rd3x@linuxmail.org>

pkgname=guake
pkgver=0.4.3
pkgrel=1
pkgdesc='Drop-down terminal for GNOME'
arch=('i686' 'x86_64')
url="http://guake.org/"
license=('GPL')
depends=('python-notify' 'vte' 'python2-gconf' 'dbus-python' 'pyxdg')
makedepends=('intltool')
options=('!libtool')
install=$pkgname.install
source=(http://guake.org/files/$pkgname-$pkgver.tar.gz
        guake-fix-notification.patch
        guake-fix-pref.desktop.patch)
md5sums=('951e42f3c6b24912baab2f4f6c84e658'
         '0b57227e6869dd84dd4fb0794ed0d082'
         '0e042a6ac89f5e77c45a96c42494bc3d')

build() {
  cd "$srcdir/$pkgname-$pkgver"
  sed -i 's|schemadir = $(sysconfdir)/gconf/schemas|schemadir = $(GCONF_SCHEMA_FILE_DIR)|' data/Makefile.in
  sed -i 's|/usr/bin/env python|/usr/bin/python2|' src/{guake{,-prefs},prefs.py}

  # http://guake.org/ticket/416
  patch -Np1 -i "$srcdir/guake-fix-notification.patch"

  # http://guake.org/ticket/448
  patch -Np1 -i "$srcdir/guake-fix-pref.desktop.patch"

  # Do not disable autostart in GNOME
  sed -i '/X-GNOME-Autostart-enabled/ d' data/guake.desktop.in

  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
              --disable-static --disable-schemas-install \
              --with-gconf-schema-file-dir=/usr/share/gconf/schemas \
              PYTHON=python2
  make
}

package() {
  cd "$srcdir/$pkgname-$pkgver"

  make DESTDIR="$pkgdir" install

  # Remove autostart file
  rm -r "$pkgdir/etc"
}