# $Id: PKGBUILD 97779 2013-09-29 16:22:26Z jlichtblau $
# Maintainer: Jaroslav Lichtblau <dragonlord@aur.archlinux.org>
# Contributor: Giovanni Scafora <giovanni@archlinux.org>
# Contributor: Daniel J Griffiths <ghost1227@archlinux.us>

pkgname=html2text
pkgver=1.3.2a
pkgrel=10
pkgdesc="A HTML to text converter"
arch=('i686' 'x86_64')
url="http://www.mbayer.de/html2text"
license=('GPL2')
depends=('gcc-libs')
makedepends=('patch')
source=(http://ftp.ibiblio.org/pub/linux/apps/www/converters/${pkgname}-${pkgver}.tar.gz \
        http://www.mbayer.de/html2text/downloads/patch-amd64-html2text-1.3.2a.diff)
sha256sums=('000b39d5d910b867ff7e087177b470a1e26e2819920dcffd5991c33f6d480392'
            'b05c425ce431de104dc0c506786f07590895195911e09c9cba62a64974ca05a0')

build() {
  cd ${srcdir}/${pkgname}-${pkgver}

#FS#35920 fix
  patch -Np1 < ${srcdir}/patch-amd64-html2text-1.3.2a.diff
  
  ./configure
  make
}

package() {
  cd ${srcdir}/${pkgname}-${pkgver}

  install -D -m755 $pkgname ${pkgdir}/usr/bin/$pkgname
  install -D -m644 $pkgname.1.gz ${pkgdir}/usr/share/man/man1/$pkgname.1.gz
  install -D -m644 html2textrc.5.gz ${pkgdir}/usr/share/man/man5/html2textrc.5.gz
}