# $Id: PKGBUILD 96438 2013-08-28 21:10:55Z lcarlier $
# Maintainer : Laurent Carlier <lordheavym@gmail.com>
# Contributor: Giovanni Scafora <giovanni@archlinux.org>
# Contributor: Alessio 'mOlOk' Bolognino <themolok@gmail.com>

pkgname=iasl
pkgver=20130823
pkgrel=1
pkgdesc="Intel ACPI Source Language compiler"
arch=('i686' 'x86_64' 'mips64el')
url="http://acpica.org"
license=('custom')
depends=('glibc')
makedepends=('flex' 'bison')
options=('!makeflags')
#install=iasl.install
source=(http://acpica.org/sites/acpica/files/acpica-unix-${pkgver}.tar.gz
	LICENSE)
md5sums=('7846a62551352d7dae6f93f8255e9d99'
         '8615526144f69ea4e870d9bc37df9b29')

build() {
  cd "${srcdir}/acpica-unix-${pkgver}"/generate/unix

  #sed -i -e 's/_CYGWIN/_LINUX/g' -e 's/-Werror//g' Makefile.config

  if [[ $CARCH == i686 ]]; then
    make BITS=32
  elif [[ $CARCH == x86_64 ]]; then
    make BITS=64
  else
    sed -i 's|$(BITSFLAG)||g' Makefile.config
    make
  fi
}

package() {
  cd "${srcdir}/acpica-unix-${pkgver}"/generate/unix

  make DESTDIR=${pkgdir} install

  install -D -m644 "${srcdir}/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
md5sums=('cc7528ecd185ff779c6b58bfede091b2'
         '8615526144f69ea4e870d9bc37df9b29')