# $Id: PKGBUILD 102761 2013-12-19 11:22:34Z fyan $
# Maintainer: Felix Yan <felixonmars@gmail.com>
# Contributor: Thomas Dziedzic < gostrc at gmail >
# Contributor: Rainy <rainylau(at)gmail(dot)com>
# Contributor: Lee.MaRS <leemars@gmail.com>
# Contributor: Hiroshi Yui <hiroshiyui@gmail.com>

pkgname=ibus-chewing
pkgver=1.4.4
pkgrel=1
pkgdesc='Chinese Chewing Engine for IBus Framework'
arch=('i686' 'x86_64')
license=('GPL')
url='http://ibus.googlecode.com'
depends=('ibus' 'libchewing' 'libxtst' 'gconf')
makedepends=('swig' 'cmake' 'gob2')
install=ibus-chewing.install
source=("http://ibus.googlecode.com/files/${pkgname}-${pkgver}-Source.tar.gz")

build() {
  cd ${pkgname}-${pkgver}-Source
  cmake . -DCMAKE_INSTALL_PREFIX=/usr \
    -DSYSCONF_INSTALL_DIR=/usr/share \
    -DLIBEXEC_DIR=/usr/lib/ibus
  make
}

package() {
  cd ${pkgname}-${pkgver}-Source
  make DESTDIR="${pkgdir}" install

  mkdir -p "$pkgdir/usr/share/gconf/schemas"
  mv "$pkgdir/etc/gconf/schemas/${pkgname}.schemas" "$pkgdir/usr/share/gconf/schemas/"
  rm -r "$pkgdir/etc"
}

sha512sums=('47581bca46d1a8f0f10f13887d5db37cf1ca3531e1a05fea516ea10fec59d4b0c2f629b5a291b1aed77e642efa3d456670c8f7fcaff460b187e3b7fc8220f2d6')