# $Id: PKGBUILD 90559 2013-05-13 07:47:15Z lfleischer $
# Maintainer:
# Contributor: Andrea Scarpino <andrea@archlinux.org>
# Contributor: Andreas Radke <andyrtr@archlinux.org>
# Contributor: Jason Chu <jchu@xentac.net>

pkgname=icecast
pkgver=2.3.3
pkgrel=4
pkgdesc='Streaming audio over the Internet'
arch=('i686' 'x86_64')
license=('GPL')
url='http://www.icecast.org/'
depends=('libxslt' 'libvorbis' 'curl' 'speex' 'libtheora')
backup=('etc/icecast.xml'
        'etc/logrotate.d/icecast')
source=("http://downloads.us.xiph.org/releases/${pkgname}/${pkgname}-${pkgver}.tar.gz"
        'icecast.logrotate'
        'start-by-nobody.patch'
        'icecast.service')
md5sums=('2b5d1b40778922e5f6431b7758c359ad'
         '59c6552bcb1dd9fb542af8670dfabd3c'
         'd8e929d2214123a1954da4383bf16583'
         '1468e59f76de194579b615889e20198f')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  patch -Np1 -i "${srcdir}/start-by-nobody.patch"

  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  make DESTDIR="${pkgdir}" install

  # install man page
  sed -i -e 's/icecast2/icecast/g' debian/icecast2.1
  install -Dm644 debian/icecast2.1 "${pkgdir}/usr/share/man/man1/icecast.1"

  # install logrotate config (taken from Fedora)
  install -Dm644 "${srcdir}/icecast.logrotate" "${pkgdir}/etc/logrotate.d/icecast"

  # create log directory
  install -d -g99 -o99 "${pkgdir}/var/log/icecast"

  # install systemd unit
  install -Dm0644 "${srcdir}/icecast.service" "${pkgdir}/usr/lib/systemd/system/icecast.service"
}