# $Id: PKGBUILD 101265 2013-11-21 12:14:23Z bpiotrowski $
# Maintainer: Ionut Biru <ibiru@archlinux.org>

pkgname=js185
pkgver=1.0.0
pkgrel=2
pkgdesc="JavaScript interpreter and libraries (legacy)"
arch=(i686 x86_64 mips64el)
url="https://developer.mozilla.org/En/SpiderMonkey/1.8.5"
license=(MPL)
depends=(nspr gcc-libs)
makedepends=(python2 zip)
options=(!staticlibs)
source=(http://ftp.mozilla.org/pub/mozilla.org/js/$pkgname-$pkgver.tar.gz)
md5sums=('a4574365938222adca0a6bd33329cb32')

build() {
  cd js-1.8.5/js/src

  if [ "$CARCH" = "mips64el" ]; then
     #Force disabling JIT.
     sed -ri 's/#define ENABLE_(JIT|ASSEMBLER) 1/#define ENABLE_\1 0/' \
         assembler/wtf/Platform.h
     sed -ri 's/ENABLE_(JIT|ASSEMBLER)=1/ENABLE_\1=0/' Makefile.{in,ref}
     extraconf="--disable-methodjit --disable-tracejit"
  fi

  # _FORTIFY_SOURCE causes configure error
  unset CPPFLAGS

  ./configure --prefix=/usr --with-system-nspr \
     --enable-threadsafe $extraconf
  make
}

package() {
  cd js-1.8.5/js/src
  make DESTDIR="$pkgdir" install
  install -Dm755 shell/js "$pkgdir/usr/bin/js"
  find "$pkgdir"/usr/{lib/pkgconfig,include} -type f -exec chmod -x {} +

  # Bad symlinks (absolute, including DESTDIR!)
  cd "$pkgdir/usr/lib"
  ln -sf libmozjs185.so.1.0.0 libmozjs185.so.1.0
  ln -sf libmozjs185.so.1.0 libmozjs185.so
}

# vim:set ts=2 sw=2 et: