# $Id: PKGBUILD 91296 2013-05-20 21:10:18Z foutrelis $
# Maintainer:
# Contributor: Mateusz Herych <heniekk@gmail.com>
# Contributor: Stefano Zamprogno <stefano.zamprogno@gmail.com>

pkgname=kmess
pkgver=2.0.6.2
pkgrel=2
pkgdesc="A MSN Messenger client for Linux"
arch=('i686' 'x86_64')
url='http://kmess.sourceforge.net/'
license=('GPL')
depends=('kdebase-lib')
makedepends=('automoc4' 'cmake' 'optipng')
optdepends=('cabextract: provides winks support')
install=${pkgname}.install
source=("http://downloads.sourceforge.net/${pkgname}/${pkgname}-$pkgver.tar.bz2")
md5sums=('a2e57911713308bef81b9347135cc5dd')

prepare() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  # Fix invalid PNG images to work with libpng 1.6
  find -name '*.png' -exec optipng -quiet -force -fix {} +
}

build() {
  cd "${srcdir}"
  mkdir build
  cd build
  cmake ../${pkgname}-${pkgver} \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_BUILD_TYPE=Release
  make
}

package() {
  cd "${srcdir}"/build
  make DESTDIR="${pkgdir}" install
}