# $Id: PKGBUILD 80049 2012-11-15 19:06:07Z bpiotrowski $
# Maintainer:  Bartłomiej Piotrowski <barthalion@gmail.com>
# Contributor: Unknown47 <unknown47r@gmail.com>
# Contributor: Angel Velasquez <angvp@archlinux.org>
# Contributor: Juergen Hoetzel <juergen@archlinux.org>

pkgname=libfm
pkgver=1.1.0
pkgrel=3
pkgdesc='Library for file management'
url='http://pcmanfm.sourceforge.net/'
arch=('i686' 'x86_64' 'mips64el')
license=('GPL')
groups=('lxde')
options=('!libtool')
install=libfm.install
depends=('gtk2' 'menu-cache' 'shared-mime-info' 'udisks' 'desktop-file-utils' 'vala')
source=(http://downloads.sourceforge.net/pcmanfm/$pkgname-$pkgver.tar.gz)
md5sums=('a5bc8b8291cf810c659bfb3af378b5de')

build() {
  cd $srcdir/$pkgname-$pkgver

  ./configure --prefix=/usr \
    --sysconfdir=/etc \
    --enable-udisks \
    --with-gnu-ld 
  make LDFLAGS+=' -lgobject-2.0 -lglib-2.0'
}

package() {
  cd $srcdir/$pkgname-$pkgver
  make DESTDIR=$pkgdir install

  # Temporary fix to FS#32361
  rm $pkgdir/usr/include/libfm
  mv $pkgdir/usr/include/libfm-1.0/ $pkgdir/usr/include/libfm 
}