# $Id: PKGBUILD 64884 2012-02-18 19:31:38Z arodseth $
# Maintainer: Alexander Rødseth <rodseth@gmail.com>
# Contributor: Brad Fanella <bradfanella@archlinux.us>
# Contributor: Paulo Matias <matiasΘarchlinux-br·org>
# Contributor: Daniel J Griffiths <ghost1227@archlinux.us>

pkgname=libparserutils
pkgver=0.1.1
pkgrel=2
pkgdesc="Library for building efficient parsers"
arch=('i686' 'x86_64' 'mips64el')
url="http://www.netsurf-browser.org/projects/libparserutils"
license=('MIT')
source=("http://www.netsurf-browser.org/projects/releases/$pkgname-$pkgver-src.tar.gz")
depends=('glibc')
sha256sums=('2d3f1887d3027b7df1fcacd5f74aba16d3c22a86c169816cd712857a1be0aaf3')

build() {
	cd "$srcdir/$pkgname-$pkgver"

	sed 's:-Wall::' -i Makefile
	make PREFIX=/usr COMPONENT_TYPE="lib-shared"
	make PREFIX=/usr COMPONENT_TYPE="lib-static"
}

package() {
	cd "$srcdir/$pkgname-$pkgver"

	make install PREFIX=/usr DESTDIR="$pkgdir" COMPONENT_TYPE="lib-shared" 
	make install PREFIX=/usr DESTDIR="$pkgdir" COMPONENT_TYPE="lib-static"
	install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}

# vim:set ts=2 sw=2 et: