# Maintainer: Sven-Hendrik Haase <sh@lutzhaase.com>
# Contributor: Linus Sjögren <thelinx@unreliablepollution.net>
# Contributor: Eric Forgeot < http://anamnese.online.fr >, dreeze
pkgname=love08
pkgver=0.8.0
pkgrel=1
pkgdesc="An open-source 2D game engine which uses the versatile Lua scripting language to create dynamic gaming experiences"
arch=(i686 x86_64)
url="http://love2d.org/"
license=('zlib')
depends=('luajit' 'physfs' 'freetype2' 'devil' 'mpg123' 'openal' 'libvorbis' 'libmodplug' 'sdl' 'shared-mime-info' 'hicolor-icon-theme' 'desktop-file-utils' 'libgl' 'glu')
makedepends=('mesa')
source=("https://bitbucket.org/rude/love/downloads/love-${pkgver}-linux-src.tar.gz")
md5sums=('9db9c32585fc7c7da3eba7e438783099')

build() {
  cd "$srcdir"/love-$pkgver
  sed -i "s|freetype/|freetype2/|g" src/modules/font/freetype/{TrueTypeRasterizer.h,Font.h}
  ./configure --program-suffix=08 --prefix=/usr --with-luajit
  make
}

package() {
  cd "$srcdir"/love-$pkgver

  make DESTDIR="$pkgdir" install

  install -Dm0644 "license.txt" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}

# vim:set ts=2 sw=2 et: