# $Id: PKGBUILD 62343 2012-01-19 11:02:08Z cbrannon $
# Maintainer: Chris Brannon <cmbrannon79@gmail.com>
# Contributor: Geoffroy Carrier <geoffroy@archlinux.org>

pkgname=luarocks
pkgver=2.0.7.1
pkgrel=1
pkgdesc='Deployment and management system for Lua modules'
arch=('i686' 'x86_64' 'mips64el')
url="http://luarocks.org/"
depends=('lua' 'unzip' 'zip' 'curl')
optdepends=('cvs: for fetching sources from CVS repositories'
            'git: for fetching sources from git repositories'
            'mercurial: for fetching sources from mercurial repositories'
            'luasec: HTTPS support'
            'cmake: for building rocks that use the cmake build system')
license=('custom')
options=('!makeflags')
source=(http://luarocks.org/releases/$pkgname-$pkgver.tar.gz)

build() {
  cd "$srcdir/$pkgname-$pkgver"

  # I added --with-downloader=curl, because luarocks already uses curl
  # for uploading.  May as well use curl for downloading.
  ./configure --prefix=/usr --sysconfdir=/etc/luarocks --with-downloader=curl
  make 
}

package() {
  cd "$srcdir/$pkgname-$pkgver"
  make install DESTDIR="$pkgdir"
  install -D COPYING "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}

md5sums=('37003e5c78792e353acde684426bdeac')