# $Id: PKGBUILD 101650 2013-11-29 19:09:30Z arcanis $
# Maintainer: Evgeniy Alekseev <arcanis.arch at gmail dot com>
# Contributor: Simon Perry <pezz at sanxion dot net>
# Contributor: Sigitas Mazaliauskas <sigisnn at gmail dot com>
# Contributor: LinkMaster03 <linkmaster032000 at gmail dot com>

pkgname=mangler
pkgver=1.2.5
pkgrel=2
pkgdesc="Ventrilo compatible VOIP client for Linux"
arch=('i686' 'x86_64')
url="http://www.mangler.org/"
license=('GPL3')
depends=('dbus-glib' 'gsm' 'gtkmm' 'libpulse' 'speex')
makedepends=('librsvg' 'pkg-config')
optdepends=('alsa-lib: ALSA support'
            'celt: CELT codec support'
            'espeak: TTS support'
            'g15daemon: G15 keyboard support'
            'xosd: Information overlay support')
conflicts=('mangler-svn')
source=(http://www.mangler.org/downloads/$pkgname-$pkgver.tar.bz2)
md5sums=('28bb40c91d8e778a95a0845f858be503')
options=(!libtool)

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  ./configure --prefix=/usr
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
}