# $Id: PKGBUILD 56067 2011-09-30 09:08:26Z spupykin $
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: William Rea <sillywilly@gmail.com>

pkgname=medit
pkgver=1.0.4
pkgrel=1
pkgdesc="A GTK text editor"
arch=('i686' 'x86_64')
url="http://mooedit.sourceforge.net"
options=('!emptydirs')
license=('GPL')
depends=('pygtk' 'libxml2' 'pcre' 'libsm' 'python2' 'gtk2' 'gcc-libs')
optdepends=('ctags' 'vte: terminal emulator')
makedepends=(pkgconfig perlxml intltool gcc-objc)
install=medit.install
source=(http://downloads.sourceforge.net/mooedit/medit-$pkgver.tar.bz2)
md5sums=('dc3a24e7f23deaa21f59d221fd321131')

build() {
  cd $srcdir/medit-$pkgver
  export PYTHON=/usr/bin/python2
  [ -f Makefile ] || ./configure --prefix=/usr
  make
}

package() {
  cd $srcdir/medit-$pkgver
  make DESTDIR=${pkgdir} install
  cd ${pkgdir}/usr/share/medit-1/language-specs
  sed -i "s|*.sh|*.sh;PKGBUILD|" sh.lang
  rm -rf $pkgdir/usr/share/mime
  rm -rf $pkgdir/usr/share/icons/hicolor/icon-theme.cache
}