# $Id: PKGBUILD 60139 2011-12-05 22:27:28Z svenstaro $
# Maintainer: Sven-Hendrik Haase <sh@lutzhaase.com>
# Contributor: Larry Hajali <larryhaja [at] gmail [dot] com>
 
pkgname=megaglest
pkgver=3.6.0.1
_pkgver=3.6.0
pkgrel=1
pkgdesc="Fork of Glest, a 3D real-time strategy game in a fantastic world."
arch=('i686' 'x86_64')
url="http://sourceforge.net/projects/megaglest/"
license=('GPL3')
depends=('curl' 'megaglest-data' 'xerces-c' 'sdl' 'libvorbis' 'openal' 'mesa' 'lua' 'icu' 'ftgl' 'glew')
makedepends=('ftjam' 'p7zip' 'wxgtk' 'cmake')
source=("http://downloads.sourceforge.net/project/${pkgname}/current_release/${pkgname}-source-${pkgver}.tar.xz")
md5sums=('099a35b97e101aa2b8facf144a5d96c8')

build() {
  cd "${srcdir}"/"${pkgname}"-"${_pkgver}"/

  [[ -d build ]] && rm -r build
  mkdir build && cd build
  cmake .. \
   -DWANT_SVN_STAMP=OFF \
 	 -DCMAKE_INSTALL_PREFIX=/usr \
   -DCMAKE_BUILD_TYPE=Release # set =Debug for debugging version
  make
}

package() {
  cd "${srcdir}"/"${pkgname}"-"${_pkgver}"/

  cd build
  make DESTDIR="$pkgdir" install
}

# vim: sw=2:ts=2 et: