# $Id: PKGBUILD 94988 2013-08-02 13:05:49Z arodseth $
# Maintainer:  Alexander Rødseth <rodseth@gmail.com>
# Contributor:  Bartłomiej Piotrowski <nospam@bpiotrowski.pl>
# Contributor: Andreas Radke <andyrtr@archlinux.org>
# Contributor: rabyte <rabyte.at.gmail.dot.com>
# Contributor: Johannes Krampf <wuischke.at.amule.dot.org>
# Contributor: Bartłomiej Piotrowski <barthalion@gmail.com>

pkgname=midori-gtk3
pkgver=0.5.4
pkgrel=2
pkgdesc='Lightweight web browser (GTK3)'
arch=('x86_64' 'i686')
url='http://www.midori-browser.org/'
license=('LGPL2.1')
install='midori.install'
conflicts=('midori')
provides=('midori')
depends=('libzeitgeist' 'webkitgtk' 'libnotify' 'libxss' 'hicolor-icon-theme' 'desktop-file-utils' 'libunique3' 'gcr')
makedepends=('pkg-config' 'bzr' 'python2' 'libxml2' 'gtk3' 'intltool' 'python2-docutils' 'libsoup' 'vala' 'librsvg')
optdepends=('gstreamer0.10-ugly-plugins: HTML5 videos support'
            'aria2: download utility')
options=('!emptydirs')
source=("http://www.midori-browser.org/downloads/midori_${pkgver}_all_.tar.bz2")
sha256sums=('d4ee77f3dd9bf2c07cea7674d533e77960e9346bd8b5482582ccb3cdaf182022')

build() {
  cd "$srcdir/midori_${pkgver}_all_"

  # if granite is present, the build fails (last time I tried)
  python2 ./waf configure \
    --prefix=/usr \
    --enable-gtk3 \
    --disable-granite \
    --enable-webkit2
  python2 ./waf build 
}

package() {
  cd "$srcdir/midori_${pkgver}_all_"

  DESTDIR="$pkgdir" python2 ./waf install
}

# vim:set ts=2 sw=2 et: