# $Id: PKGBUILD 88664 2013-04-21 13:23:51Z arodseth $
# Maintainer: Alexander Rødseth <rodseth@gmail.com>
# Contributor: Christopher O'Neill <milkytracker@chrisoneill.co.uk>
# Contributor: Maks Verver <maksverver@geocities.com>

pkgname=milkytracker
pkgver=0.90.85
pkgrel=8
pkgdesc='Fast Tracker II inspired music tracker'
arch=('x86_64' 'i686')
url="http://www.milkytracker.org/"
license=('GPL3')
depends=('sdl' 'alsa-lib' 'zlib' 'gcc-libs')
makedepends=('jack-audio-connection-kit' 'gendesk')
optdepends=('jack-audio-connection-kit: JACK audio support')
options=('docs' '!strip')
install="$pkgname.install"
source=("http://milkytracker.org/files/$pkgname-$pkgver.tar.bz2"
        "$pkgname.patch")
sha256sums=('59a0d294d63752be74b157e07b0c70252c9198c312d9b1ad0ca460129fe5bd80'
            '0b701bf97375343f13d1af8a30df052c85b526e527bf6402634c37c7e9fa5b42')
_name=('MilkyTracker')
_categories=('AudioVideo;Audio;AudioVideoEditing;')

prepare() {
  cd "$srcdir"

  gendesk -n
  patch -p0 -i "$pkgname.patch"
}

build() {
  cd "$pkgname-$pkgver"

  ./configure --prefix=/usr --with-alsa --with-jack
  make
}

package() {
  cd "$srcdir/$pkgname-$pkgver"

  make DESTDIR="$pkgdir" install
  mkdir -p "$pkgdir/usr/share/applications" \
    "$pkgdir/usr/share/doc/milkytracker"
  install -Dm644 resources/pictures/carton.png \
    "$pkgdir/usr/share/pixmaps/milkytracker.png"
  install -m644 "$srcdir/milkytracker.desktop" \
    "$pkgdir/usr/share/applications"
  install -m644 docs/ChangeLog.html "$pkgdir/usr/share/doc/milkytracker"
  install -m644 docs/MilkyTracker.html "$pkgdir/usr/share/doc/milkytracker"
  install -m644 docs/readme_unix "$pkgdir/usr/share/doc/milkytracker"
  install -m644 docs/FAQ.html "$pkgdir/usr/share/doc/milkytracker"
}

# vim:set ts=2 sw=2 et: