# $Id: PKGBUILD 73526 2012-07-09 06:06:23Z spupykin $
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Maintainer:Biginoz < biginoz AT free point fr>
# Contributor: Ignacio Galmarino <igalmarino@gmail.com>
# Contributor: Matthias Sobczyk <matthias.sobczyk@googlemail.com>
# Contributor: Kamil Kaminski <kyle@kkaminsk.com>

pkgname=minidlna
pkgver=1.0.24
pkgrel=5
pkgdesc="A DLNA/UPnP-AV Media server (aka ReadyDLNA)"
arch=('i686' 'x86_64')
url="http://sourceforge.net/projects/minidlna/"
license=('GPL')
depends=('libexif' 'libjpeg' 'libid3tag' 'flac' 'libvorbis' 'ffmpeg-compat' 'sqlite')
conflicts=('minidlna-cvs')
backup=('etc/minidlna.conf'
	'etc/conf.d/minidlna')
changelog=changelog
source=(http://downloads.sourceforge.net/minidlna/minidlna_${pkgver}_src.tar.gz
	minidlna.rc
	minidlna.conf
	minidlna.service
	ffmpeg-compat.patch)
md5sums=('be9b4c91e3fcde592dc3f9828098ca0f'
         'c9863d5703e0a8469cc200f2739567e7'
         'af1b8c0fef9902f797b0324c255da5a1'
         '1903ed9ceee43b8bb86146b9ad8eb50c'
         '310d66170f20d660e96f4c9709559ed1')

build() {
  cd "$srcdir/$pkgname-$pkgver"
  patch -p1 <$srcdir/ffmpeg-compat.patch
  sed -i 's|DB_PATH=.*|DB_PATH=/var/cache/minidlna|' genconfig.sh
  make
}

package() {
  cd "$srcdir/$pkgname-$pkgver"
  DESTDIR=$pkgdir make install
  install -Dm644 minidlna.conf ${pkgdir}/etc/minidlna.conf

  install -Dm755 ${srcdir}/minidlna.rc ${pkgdir}/etc/rc.d/minidlna
  mkdir -p $pkgdir/etc/conf.d
  echo 'MINIDLNA_USER=nobody' >$pkgdir/etc/conf.d/minidlna
  echo 'MINIDLNA_OPTS=""' >>$pkgdir/etc/conf.d/minidlna

  # systemd files
  install -Dm0644 $srcdir/minidlna.conf $pkgdir/usr/lib/tmpfiles.d/minidlna.conf
  install -Dm0644 $srcdir/minidlna.service $pkgdir/usr/lib/systemd/system/minidlna.service
}