# $Id: PKGBUILD 61280 2011-12-28 01:40:23Z seblu $
# Maintainer: Lukas Fleischer <archlinux at cryptocrack dot de>
# Contributor: Ali H. Caliskan <ali.h.caliskan AT gmail DOT com>
# Contributor: Ryan Coyner <rcoyner@gmail.com>
# Contributor: Stefan Husmann <stefan-husmann@t-online.de>

pkgname=mixxx
pkgver=1.10.0
pkgrel=1
pkgdesc="Free, open source software for digital DJ'ing."
arch=('i686' 'x86_64')
url='http://www.mixxx.org'
license=('GPL')
depends=('fftw' 'libid3tag' 'libmad' 'libogg' 'libshout' 'libsndfile' 'portaudio' 'portmidi'
         'qt>=4.5' 'taglib' 'qtwebkit')
makedepends=('mesa' 'scons' 'libshout')
source=("http://downloads.mixxx.org/${pkgname}-${pkgver}/${pkgname}-${pkgver}-src.tar.gz")
md5sums=('d92bf422491fa92adf7ed6c2998e67fb')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  # GCC segfault workaround (fixes FS#26716)
  CFLAGS=${CFLAGS/-D_FORTIFY_SOURCE=2/}

  scons qtdir=/usr/lib/qt prefix=/usr install_root="${pkgdir}/usr"
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  # GCC segfault workaround (fixes FS#26716)
  CFLAGS=${CFLAGS/-D_FORTIFY_SOURCE=2/}

  scons qtdir=/usr/lib/qt prefix=/usr install_root="${pkgdir}/usr" install
}