# $Id: PKGBUILD 85891 2013-03-08 15:20:48Z ttoepper $
# Maintainer: Thorsten Töpper <atsutane-tu@freethoughts.de>
# Contributor: Daniel Hommel <dhommel@gmail.com>

pkgname=mksh
pkgver=R44
pkgrel=1
pkgdesc='The MirBSD Korn Shell - an enhanced version of the public domain ksh'
url='https://www.mirbsd.org/mksh.htm'
license=('custom')
arch=('i686' 'x86_64')
install=mksh.install
source=("https://www.mirbsd.org/MirOS/dist/mir/mksh/$pkgname-$pkgver.tgz"
        'https://www.mirbsd.org/TaC-mksh.txt')
depends=('gcc-libs')
md5sums=('fe011686319a8c50d5e237fd5e195fd8'
         'bd05936e20d699df5d47e4ad6223c9d4')

build() {
  cd "$srcdir/$pkgname"

  sh Build.sh -r -c lto
  ./test.sh
  gzip -n9 mksh.1
}

package() {
  cd "$srcdir/$pkgname"
  install -D -m 755 mksh "$pkgdir/bin/mksh"
  install -D -m 644 mksh.1.gz "$pkgdir/usr/share/man/man1/mksh.1.gz"
  install -D -m 644 dot.mkshrc "$pkgdir/etc/skel/.mkshrc"
  install -D -m 644 "$srcdir/TaC-mksh.txt" "$pkgdir/usr/share/licenses/mksh/TaC-mksh.txt"
}

# vim:set ts=2 sw=2 et: