# $Id: PKGBUILD 60369 2011-12-12 10:37:01Z ttopper $
# Maintainer: Thorsten Töpper <atsutane-tu@freethoughts.de>
# Contributor: Daniel Hommel <dhommel@gmail.com>

pkgname=mksh
pkgver=R40d
pkgrel=1
pkgdesc="The MirBSD Korn Shell - an enhanced version of the public domain ksh"
url="http://mirbsd.de/mksh"
license=("custom")
makedepends=('cpio')
arch=('i686' 'x86_64')
install=mksh.install
source=("https://www.mirbsd.org/MirOS/dist/mir/mksh/$pkgname-$pkgver.cpio.gz"
        "https://www.mirbsd.org/TaC-mksh.txt")
md5sums=('c6428401103367730a95b99284bf47dc'
         '5376e528781247238d103ac24aceaf3d')

build() {
  cd "$srcdir"
  # makepkg can't extract cpio files
  cpio -mid < "$pkgname-$pkgver.cpio"

  cd "$srcdir/$pkgname"
  sh Build.sh -r -c lto
  ./test.sh
  gzip -n9 mksh.1
}

package() {
  cd "$srcdir/$pkgname"
  install -D -m 755 mksh "$pkgdir/bin/mksh"
  install -D -m 644 mksh.1.gz "$pkgdir/usr/share/man/man1/mksh.1.gz"
  install -D -m 644 dot.mkshrc "$pkgdir/etc/skel/.mkshrc"
  install -D -m 644 "$srcdir/TaC-mksh.txt" "$pkgdir/usr/share/licenses/mksh/TaC-mksh.txt"
}

# vim:set ts=2 sw=2 et: