# $Id: PKGBUILD 79557 2012-11-07 13:12:21Z spupykin $
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: Fabian Schoelzel <myfirstname.mylastname@googlemail.com>
# Contributor: funkyou <spamopfer@nickname.berlin.de>
# Contributor: tardo <tardo@nagi-fanboi.net>
# Contributor: Stefan Husmann <stefan-husmann@t-online.de>

pkgbase=mlt
pkgname=('mlt' 'mlt-python-bindings')
pkgver=0.8.2
pkgrel=3
pkgdesc="An open source multimedia framework"
arch=('i686' 'x86_64' 'mips64el')
url="http://www.mltframework.org"
license=('GPL')
makedepends=('sdl_image' 'libsamplerate' 'libdv' 'qt' 'sox' 'libxml2' 'gtk2' 'ffmpeg'
	     'frei0r-plugins' 'swig' 'python2' "jack" "ladspa")
source=(http://downloads.sourceforge.net/sourceforge/$pkgname/$pkgname-$pkgver.tar.gz
	ffmpeg.patch)
md5sums=('c7a8c4ca7485bb615cbcf851d8742a1c'
         'c28b4691d1715432d4de0055f4e2f5eb')

build() {
  # mlt
  cd "$srcdir/mlt-$pkgver"

  patch -p1 <$srcdir/ffmpeg.patch

  [ $CARCH == "i686" ] && SSE2=--disable-sse2 || SSE2=
#  SSE2=--disable-sse2

  msg "SSE2=$SSE2"
  ./configure --prefix=/usr --enable-gpl --enable-gpl3 \
	--qimage-libdir=/usr/lib/ --qimage-includedir=/usr/include/Qt \
	--avformat-vdpau \
	--avformat-swscale $SSE2
  make

  # mlt python bindings
  cd "$srcdir/mlt-$pkgver/src/swig/python"
  sed -i 's_path=`which python_path=`which python2_' build
  sed -i 's_`python -c_`python2 -c_' build
  sed -i 's#python-config#python2-config#' build
  ./build
}

package_mlt() {
  depends=('sdl_image' 'libsamplerate' 'libdv' 'sox' 'libxml2' 'ffmpeg' 'frei0r-plugins')
  optdepends=('jack' 'libexif' 'qt' 'gtk2' "ladspa")
  conflicts=('mlt++<=0.3.8')

  cd "$srcdir/mlt-$pkgver"
  make DESTDIR="$pkgdir" install
}

package_mlt-python-bindings() {
  depends=('python2' 'mlt')

  cd "$srcdir/mlt-$pkgver/src/swig/python"
  mkdir -p "$pkgdir/usr/lib/python2.7/"
  install -m755 mlt.py "$pkgdir/usr/lib/python2.7/"
  install -m755 _mlt.so "$pkgdir/usr/lib/python2.7/"
  install -m755 mlt_wrap.o "$pkgdir/usr/lib/python2.7/"
}