# $Id: PKGBUILD 66640 2012-02-26 16:44:34Z jlichtblau $
# Maintainer: Jaroslav Lichtblau <dragonlord@aur.archlinux.org>

pkgname=mp3splt-gtk
pkgver=0.7.1
pkgrel=1
pkgdesc="Split mp3 and ogg files without decoding"
arch=('i686' 'x86_64')
url="http://mp3splt.sourceforge.net/"
license=('GPL')
depends=('desktop-file-utils' 'gstreamer0.10-ffmpeg' 'gtk2' 'libmp3splt')
makedepends=('pkgconfig')
install=$pkgname.install
changelog=$pkgname.changelog
source=(http://downloads.sourceforge.net/sourceforge/mp3splt/$pkgname-$pkgver.tar.gz \
        $pkgname.desktop)
sha256sums=('b3f54a62dae55cfabab7aff3ae2f5627093dee27675635b04b425f3214bcdd62'
            'a50dd43c28a723c824d658b9468ff3719dcc302c57ecb3b122124e63c20800ed')

build() {
  cd ${srcdir}/$pkgname-$pkgver

  ./configure --prefix=/usr --disable-gnome --disable-mp3splttest --disable-audacious
  make
}

package() {
  cd ${srcdir}/$pkgname-$pkgver
  make DESTDIR=${pkgdir} install

#install .desktop file
  install -D -m644 ${srcdir}/$pkgname.desktop \
    ${pkgdir}/usr/share/applications/$pkgname.desktop
}