# $Id: PKGBUILD 88818 2013-04-23 01:19:34Z eric $
# Maintainer:  Bartłomiej Piotrowski <nospam@bpiotrowski.pl>
# Contributor: Martin Panter <vadmium+aur@gmail.com>
# Contributor: Stéphane Gaudreault <stephane@archlinux.org>

pkgname=mplayer2
pkgver=20130309
pkgrel=1
pkgdesc='Advanced general-purpose media player. A fork of the original MPlayer project'
arch=('i686' 'x86_64' 'mips64el')
license=('GPL')
url="http://www.mplayer2.org/"
install=$pkgname.install
depends=('a52dec' 'aalib' 'cdparanoia' 'desktop-file-utils' 'enca' 'faad2' 'ffmpeg'
         'fontconfig' 'freetype2' 'jack' 'ladspa' 'lame' 'libass' 'libbluray'
         'libcaca' 'libcdio-paranoia' 'libdca' 'libdvdcss' 'libdvdnav' 'libdvdread'
         'libjpeg' 'libmad' 'libpulse' 'libquvi' 'libtheora'
         'libxinerama' 'libxss' 'libxv' 'libxxf86dga' 'libxxf86vm'
         'mpg123' 'ncurses' 'sdl' 'ttf-dejavu')
makedepends=('unzip' 'python' 'python-docutils')
if [ "$CARCH" != "mips64el" ]; then
  depends+=('libgl' 'libvdpau' 'lirc-utils')
  makedepends+=('mesa' 'mesa-libgl' 'yasm')
fi
backup=('etc/mplayer/codecs.conf' 'etc/mplayer/input.conf')
provides=('mplayer')
conflicts=('mplayer')
options=(!emptydirs)
source=(ftp://ftp.archlinux.org/other/community/$pkgname/$pkgname-$pkgver.tar.xz{,.sig})
sha256sums=('03aeccbd82b3598e0656b54ae6ab60c79afdb78eabe1b2915e7912db7efbd343'
            'SKIP')

build() {
  cd $pkgname-$pkgver

  sed 's/gmplayer/mplayer/g' -i etc/mplayer.desktop
  find -type f -exec sed -e 's/python3/python/' -i {} \;

  [ "$CARCH" != "mips64el" ] && extra="--enable-runtime-cpudetection"

  ./configure --prefix=/usr --confdir=/etc/mplayer \
              --enable-translation --language=all \
              --enable-joystick \
              --disable-speex \
              --disable-openal \
              --disable-libdv \
              --disable-musepack \
              $extra
  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR=$pkgdir install

  install -Dm644 etc/{codecs.conf,input.conf,example.conf} $pkgdir/etc/mplayer/
  install -dm755 $pkgdir/usr/share/mplayer/
  ln -s /usr/share/fonts/TTF/DejaVuSans.ttf $pkgdir/usr/share/mplayer/subfont.ttf

  install -dm755 $pkgdir/usr/share/applications/
  install -m 644 etc/mplayer.desktop $pkgdir/usr/share/applications/
}