# $Id: PKGBUILD 58526 2011-11-13 15:57:02Z andrea $
# Maintainer: Stefan Husmann <stefan-husmann@t-online.de
# Contributor: Cristian Maureira <saint [at] archlinux.cl>
# Contributor: Dr.Egg <rwhite @ archlinux . us>

pkgname=musescore
pkgver=1.1
pkgrel=2
pkgdesc="A music score editor written in Qt"
arch=('i686' 'x86_64')
url="http://www.musescore.org/en/"
license=('GPL')
depends=('qt' 'libsndfile' 'qtscriptgenerator')
makedepends=('cmake' 'doxygen')
optdepends=('portaudio' 'jack')
install=musescore.install
source=("http://downloads.sourceforge.net/mscore/mscore-${pkgver}.tar.bz2"
        'paths.patch')
md5sums=('68b43af92093a16f7f074c0eb560a867'
         'e5011154d217f633f21b4bb70e589510')

build() {
  cd $srcdir/mscore-${pkgver}
  export QT_PLUGINS_DIR=/usr/lib/qt/plugins
  [ -d build ] && make clean
  patch -p1 < $srcdir/paths.patch
  sed -i 's+${Mscore_INSTALL_NAME}man+doc/mscore+' \
    "$srcdir"/mscore-$pkgver/mscore/manual/CMakeLists.txt
  sed -i 's+BUILD_SCRIPTGEN TRUE+BUILD_SCRIPTGEN FALSE+' \
    "$srcdir"/mscore-$pkgver/mscore/CMakeLists.txt
  sed -i 's+static_cast<const+static_cast<+' \
    $srcdir/mscore-$pkgver/mscore/mscore/exportxml.cpp
  make PREFIX=/usr release 
}
package() {
  cd $srcdir/mscore-${pkgver}
  make DESTDIR="$pkgdir" install
}