# $Id: PKGBUILD 23139 2010-08-07 06:55:11Z svenstaro $
# Maintainer: Sven-Hendrik Haase <sh@lutzhaase.com>
# Contributor: Johan Rehnberg <cleanrock@gmail.com>

pkgname=naev
pkgver=0.4.2
pkgrel=3
pkgdesc='2D action/rpg space game'
arch=('i686' 'x86_64')
url="http://code.google.com/p/naev/"
license=('GPL3')
depends=('openal' 'libvorbis' 'sdl_image' 'sdl_mixer' 'libgl' 'libxml2' 'freetype2' 'libpng' 'naev-data')
makedepends=('freeglut')
options=( )
source=("http://naev.googlecode.com/files/${pkgname}-${pkgver}.tar.bz2"
         "naev.png" "naev.desktop")
md5sums=('307bec2704e98f0af6f13e50f2737b0c'
         '5945aa4fa7c0b046ad48f2fb9cbbbdd3'
         '134032fb35eb2953e9a1bbee3a6dcf63')

build() {
  cd "$srcdir/$pkgname-$pkgver"

  ./configure --prefix=/usr --disable-debug --disable-shave --with-ndata-path=/usr/share/naev/ndata-${pkgver}
  make
}

package() {
  cd "$srcdir/$pkgname-$pkgver"

  make DESTDIR="$pkgdir/" install

  install -m644  "$srcdir/$pkgname-$pkgver/conf.example" "$pkgdir/usr/share/doc/naev/"
  
  mkdir -p "$pkgdir/usr/share/naev/"

  mkdir -p "$pkgdir/usr/share/pixmaps/"
  install -m644 "$srcdir/naev.png" "$pkgdir/usr/share/pixmaps/"

  mkdir -p "$pkgdir/usr/share/applications/"
  install -m644 "$srcdir/naev.desktop" "$pkgdir/usr/share/applications/"

  mkdir -p "$pkgdir/usr/share/licenses/naev/"
  install -m644 "$srcdir/$pkgname-$pkgver/LICENSE" "$pkgdir/usr/share/licenses/naev/"
}