# $Id: PKGBUILD 80358 2012-11-20 16:00:53Z bpiotrowski $
# Maintainer:  Bartłomiej Piotrowski
# Contributor: graysky <graysky AT archlinux DOT us>
# Contributor: Mateusz Herych <heniekk@gmail.com>
# Contributor: Army <uli[dot]armbruster[at]gmail[dot]com>

pkgname=ncmpcpp
pkgver=0.5.10
pkgrel=4
pkgdesc='Almost exact clone of ncmpc with some new features'
arch=('i686' 'x86_64' 'mips64el')
url='http://ncmpcpp.rybczak.net/'
license=('GPL')
depends=('curl' 'libmpdclient' 'taglib' 'ncurses' 'fftw')
install=ncmpcpp.install
source=(http://ncmpcpp.rybczak.net/stable/$pkgname-$pkgver.tar.bz2)
md5sums=('298ed66325bcfe358e37e186c7ea4861')

build() {
  cd $srcdir/$pkgname-$pkgver
  ./configure --prefix=/usr    \
              --enable-clock   \
              --enable-outputs \
              --enable-unicode \
              --enable-visualizer \
              --with-curl      \
              --with-fftw      \
              --with-taglib
  make
}

package() {
  cd $srcdir/$pkgname-$pkgver
  make DESTDIR=$pkgdir install

  make -C extras/
  install -Dm755 extras/artist_to_albumartist $pkgdir/usr/bin/
}