# $Id: PKGBUILD 86876 2013-03-23 23:10:35Z td123 $
# Maintainer: Jaroslav Lichtblau <dragonlord@aur.archlinux.org>
# Contributor: Sven Pfleiderer <pfleidi@roothausen.de>

pkgname=newsbeuter
pkgver=2.5
pkgrel=2
pkgdesc="A RSS feed reader for the text console with special Podcast support"
arch=('i686' 'x86_64')
url="http://www.newsbeuter.org/"
license=('custom: MIT')
depends=('curl' 'json-c' 'libxml2' 'sqlite' 'stfl')
makedepends=('swig' 'gettext')
optdepends=('ruby')
options=('!libtool')
install=$pkgname.install
changelog=$pkgname.changelog
source=(http://www.newsbeuter.org/downloads/$pkgname-$pkgver.tar.gz
        'gcc47.patch'
        'libjson.patch')
sha256sums=('abc54b7bee3e062cd166787edf35aadbeb0ae1f5fcc8d955b77143aaca096825'
            '24f30f83649deb8e2e268ebd2394243eb25824701f0c576a6c20f3f64e70dd52'
            '6fa9f8a814474e3262595745309c0263c7f3d40feb4ea8da29d2808ab710e781')

build() {
  cd ${srcdir}/$pkgname-$pkgver

  patch -p1 -i "${srcdir}"/gcc47.patch
  patch -p1 -i "${srcdir}"/libjson.patch

  make prefix=/usr
}

package() {
  cd ${srcdir}/$pkgname-$pkgver

  make prefix=/usr DESTDIR=$pkgdir install

#license
  install -D -m644 LICENSE ${pkgdir}/usr/share/licenses/$pkgname/LICENSE
}