# $Id: PKGBUILD 67996 2012-03-16 23:45:15Z giovanni $
# Contributor: Lyle Putnam <lcputnam@amerytel.net>
# Maintainer: Daenyth

pkgname=noip
pkgver=2.1.9
pkgrel=3
pkgdesc="A Dynamic DNS Client Updater for no-ip.com services"
arch=('i686' 'x86_64')
url="http://www.no-ip.com/downloads.php?page=linux"
license=('GPL')
backup=('etc/no-ip2.conf')
install=noip.install
# Note that they have the one file for the current release, so if the md5sum breaks, it means they updated.
source=("http://www.no-ip.com/client/linux/noip-duc-linux.tar.gz" 
        'noip-rc.d')
md5sums=('3b0f5f2ff8637c73ab337be403252a60'
         '63253de6f4d847015d111e5e5b20f2cf')

build() {
  cd $srcdir/$pkgname-$pkgver-1

  # Their Makefile is fucking horrid, do it by hand instead
  sed -i '/^#define CONFIG_FILEPATH/s/PREFIX//' noip2.c
  sed -i '/^#define CONFIG_FILENAME/s/PREFIX//' noip2.c
  gcc -Wall $CLFAGS $LDFLAGS -g -Dlinux -DPREFIX="/usr" noip2.c -o noip2
}

package() {
  cd $srcdir/$pkgname-$pkgver-1

  install -Dm755 noip2 $pkgdir/usr/bin/noip2
  install -Dm755 $srcdir/noip-rc.d $pkgdir/etc/rc.d/noip
}