# $Id: PKGBUILD 102181 2013-12-06 12:14:44Z giovanni $
# Maintainer: Giovanni Scafora <giovanni@archlinux.org>
# Contributor: Adam Griffiths <adam_griffithsAATTdart.net.au>

pkgname=ode
pkgver=0.12
pkgrel=5
pkgdesc="An open source, high performance library for simulating rigid body dynamics"
arch=('i686' 'x86_64')
url="http://www.ode.org"
license=('LGPL' 'BSD')
depends=('gcc-libs' 'bash')
source=("http://downloads.sourceforge.net/sourceforge/opende/${pkgname}-${pkgver}.tar.bz2")
md5sums=('48fdd41fae1a7e7831feeded09826599')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  ./configure --prefix=/usr \
              --enable-shared \
              --enable-libccd \
              --enable-double-precision
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  make DESTDIR=${pkgdir}/ install

  install -Dm0644 ${srcdir}/${pkgname}-${pkgver}/ou/LICENSE-BSD.TXT \
                  ${pkgdir}/usr/share/licenses/${pkgname}/LICENSE-BSD.TXT
  install -Dm0644 ${srcdir}/${pkgname}-${pkgver}/GIMPACT/GIMPACT-LICENSE-BSD.TXT \
                  ${pkgdir}/usr/share/licenses/${pkgname}/GIMPACT-LICENSE-BSD.TXT
  install -Dm0644 ${srcdir}/${pkgname}-${pkgver}/libccd/BSD-LICENSE \
                  ${pkgdir}/usr/share/licenses/${pkgname}/BSD-LICENSE
}