# $Id: PKGBUILD 63931 2012-02-07 13:00:00Z tredaelli $
# Maintainer: Timothy Redaelli <timothy.redaelli@gmail.com>
# Contributor: darkcoder <mario_vazq@hotmail.com>

pkgname=os-prober
pkgver=1.49
pkgrel=3
pkgdesc="Utility to detect other OSes on a set of drives"
url="http://joey.kitenet.net/code/os-prober/"
arch=('i686' 'x86_64')
license=('GPL3')
depends=('sh')
source=(ftp://ftp.debian.org/debian/pool/main/o/${pkgname}/${pkgname}_${pkgver}.tar.gz)
md5sums=('5a981493a7c16174e6454fcf6b39b1b5')
sha512sums=('473f02807bdc971d6abf976f8a708691767ba85d45b54c1c87310c62626959f30e524aca2fb08843dfc859f26bd80cbbba016235137aa87db1c4151f6e893fa4')

build() {
  cd "$srcdir/$pkgname"

  # adjust lib dir to allow detection of 64-bit distros
  sed -i -e "s:/lib/ld\*\.so\*:/lib*/ld*.so*:g" os-probes/mounted/common/90linux-distro

  rm -f Makefile
  make newns
}

package() {
  cd "$srcdir/$pkgname"

  install -Dm755 linux-boot-prober "$pkgdir"/usr/bin/linux-boot-prober
  install -Dm755 os-prober "$pkgdir"/usr/bin/os-prober
  install -Dm755 newns "$pkgdir"/usr/lib/os-prober/newns
  install -Dm755 common.sh $pkgdir/usr/share/os-prober/common.sh  

  for dir in os-probes os-probes/mounted os-probes/init linux-boot-probes linux-boot-probes/mounted; do
    install -dm755 "$pkgdir/usr/lib/$dir"
    install -m755 -t "$pkgdir/usr/lib/$dir" "$dir"/common/*
    [[ -d "$dir"/x86 ]] && install -m755 -t "$pkgdir/usr/lib/$dir" "$dir"/x86/*
  done

  install -Dm755 os-probes/mounted/powerpc/20macosx $pkgdir/usr/lib/os-probes/mounted/20macosx
  
  # create a empty labels file, will be used by os-prober at execution
  mkdir -p $pkgdir/var/lib/os-prober
  touch $pkgdir/var/lib/os-prober/labels 
  chmod 644 $pkgdir/var/lib/os-prober/labels
}