# Maintainer: Thomas Dziedzic < gostrc at gmail >
# Contributor: Michele Mocciola <mickele>
# Contributor: Simon Zilliken <simon____AT____zilliken____DOT____name>

pkgname=paraview
pkgver=3.14.0
pkgrel=2
pkgdesc='Parallel Visualization Application using VTK'
arch=('i686' 'x86_64')
url='http://www.paraview.org'
license=('custom')
depends=('qt' 'python2' 'libgl' 'unixodbc' 'postgresql-libs' 'libxt' 'qtwebkit' 'libmysqlclient' 'mesa' 'openmpi' 'boost-libs' 'libcgns2'
         # export as avi support
         'ffmpeg'
         # The following is a list of libraries we explicitly tell cmake to use the system library of
         'hdf5' 'freetype2' 'libjpeg' 'libpng' 'libtiff' 'zlib' 'expat' 'libxml2' 'libtheora'
        )
makedepends=('cmake' 'desktop-file-utils' 'boost')
source=("http://paraview.org/files/v${pkgver:0:4}/ParaView-${pkgver}-Source.tar.gz"
        'paraview.png'
        'paraview.desktop'
        'fix-build-with-zlib-1.2.6.diff'
        'ffmpeg-0.8.diff')
md5sums=('a260bd891fd75d0e276a581a3603edff'
         'db623002bc71a257ddfdd0c9c7b14c3f'
         '4e4b7172ed18171c37446fd7c4f1e8f5'
         'e4506b4ed0d2ae60072388f098be6c33'
         'e992321c9d1def6034d0fa6607b40c5a')

build() {
  cd ${srcdir}/ParaView-${pkgver}-Source

  # fix http://paraview.org/Bug/view.php?id=12924
  patch -Np0 -i ${srcdir}/fix-build-with-zlib-1.2.6.diff

  # fix http://www.vtk.org/Bug/view.php?id=12691
  cd VTK
  patch -Np1 -i ${srcdir}/ffmpeg-0.8.diff

  mkdir ${srcdir}/build
  cd ${srcdir}/build

  # flags to enable using system libs
  local cmake_system_flags=""
  for lib in HDF5 FREETYPE JPEG PNG TIFF ZLIB EXPAT LIBXML2 OGGTHEORA; do
    cmake_system_flags+="-DVTK_USE_SYSTEM_${lib}:BOOL=ON "
  done

  # flags to use python2 instead of python which is 3.x.x on archlinux
  local cmake_system_python_flags="-DPYTHON_EXECUTABLE:PATH=/usr/bin/python2 -DPYTHON_INCLUDE_DIR:PATH=/usr/include/python2.7 -DPYTHON_LIBRARY:PATH=/usr/lib/libpython2.7.so"

  # enable when http://paraview.org/Bug/view.php?id=12718 gets fixed
  #-DCMAKE_SKIP_RPATH:BOOL=YES \
  # the following flags enable the feature request at https://bugs.archlinux.org/task/27525
  # -DPARAVIEW_USE_VISITBRIDGE:BOOL=ON -DVISIT_BUILD_READER_CGNS:BOOL=ON
  cmake \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX:PATH=/usr \
    -DVTK_USE_BOOST:BOOL=ON \
    -DPARAVIEW_USE_MPI:BOOL=ON \
    -DPARAVIEW_ENABLE_PYTHON:BOOL=ON \
    -DPARAVIEW_BUILD_QT_GUI:BOOL=ON \
    -DPARAVIEW_USE_VISITBRIDGE:BOOL=ON \
    -DVISIT_BUILD_READER_CGNS:BOOL=ON \
    -DVTK_USE_FFMPEG_ENCODER:BOOL=ON \
    ${cmake_system_flags} \
    ${cmake_system_python_flags} \
    ../ParaView-${pkgver}-Source

  make
}

package() {
  cd build

  make DESTDIR=${pkgdir} install

  # Install license
  install -Dm644 ${srcdir}/ParaView-${pkgver}-Source/License_v1.2.txt ${pkgdir}/usr/share/licenses/paraview/LICENSE

  # Install desktop shortcuts
  install -Dm644 ${srcdir}/paraview.png ${pkgdir}/usr/share/pixmaps/paraview.png
  desktop-file-install --dir=${pkgdir}/usr/share/applications ${srcdir}/paraview.desktop
}