# $Id: PKGBUILD 75524 2012-08-26 20:10:27Z spupykin $
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Maintainer: TDY <tdy@gmx.com>

pkgname=parole
pkgver=0.3.0.3
pkgrel=1
pkgdesc="A modern media player based on the GStreamer framework"
arch=('i686' 'x86_64' 'mips64el')
url="http://goodies.xfce.org/projects/applications/parole/"
license=('GPL')
depends=('gstreamer0.10-base>=0.10.11' 'hicolor-icon-theme' 'libnotify>=0.4.1'
         'libxfce4ui>=4.7.0' 'taglib>=1.4' 'desktop-file-utils')
makedepends=('pkgconfig>=0.9.0' 'xfce4-dev-tools')
optdepends=('xulrunner>=1.9.1: browser plugin')
conflicts=('parole-media-player-git')
options=('!libtool')
install=parole.install
#source=(http://archive.xfce.org/src/apps/$pkgname/${pkgver%.*}/$pkgname-$pkgver.tar.bz2)
source=(http://git.xfce.org/apps/parole/snapshot/parole-$pkgver.tar.bz2)
md5sums=('19b57753085c1effb3157df0f1373f4c')

build() {
  cd "$srcdir/$pkgname-$pkgver"

  # Work around DSO linking issue
#  LDFLAGS+=' -lX11'

  [ -x configure ] || ./autogen.sh

  ./configure --prefix=/usr --libexecdir=/usr/lib --enable-taglib --enable-libnotify
  make
}

package() {
  cd "$srcdir/$pkgname-$pkgver"
  make DESTDIR="$pkgdir" install
}